***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Oct. 23, 2025                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJA3474S-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     5.04
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=16.5    VTO=2.1    LEVEL=3     VMAX=5e4 NFS=4e11  GAMMA=0.60)
Rd     d1    d2   8.481e-2     TC=5.9e-3,16.5u
Dbd     s2    d2    Dbt
.MODEL   Dbt   D  (BV=110    TBV1=5.1e-4  TBV2=-5e-7  CJO=9.948e-11   M=2.308  VJ=7.856e1)
Dbody   s2   21    DBODY
.MODEL DBODY  D   (IS=1.808e-14 N=8.859e-1  RS=4e-8  EG=1.13  TT=20n IKF=3.851e-2)
Rdiode  d1  21    2.019e-2 TC=1.5e-3
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   8.613e-11
.MODEL     DGD    D(CJO=8.613e-11   M=1.320   VJ=5.113)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    1.501e-10
.ENDS PJA3474S-AU
*$
